107 lines
4.3 KiB
CMake
107 lines
4.3 KiB
CMake
|
# - Check if given C source compiles and links into an executable
|
||
|
|
# CHECK_C_SOURCE_COMPILES(<code> <var> [FAIL_REGEX <fail-regex>])
|
||
|
|
# <code> - source code to try to compile, must define 'main'
|
||
|
|
# <var> - variable to store whether the source code compiled
|
||
|
|
# <fail-regex> - fail if test output matches this regex
|
||
|
|
# The following variables may be set before calling this macro to
|
||
|
|
# modify the way the check is run:
|
||
|
|
#
|
||
|
|
# CMAKE_REQUIRED_FLAGS = string of compile command line flags
|
||
|
|
# CMAKE_REQUIRED_DEFINITIONS = list of macros to define (-DFOO=bar)
|
||
|
|
# CMAKE_REQUIRED_INCLUDES = list of include directories
|
||
|
|
# CMAKE_REQUIRED_LIBRARIES = list of libraries to link
|
||
|
|
|
||
|
|
#=============================================================================
|
||
|
|
# Copyright 2005-2009 Kitware, Inc.
|
||
|
|
#
|
||
|
|
# Distributed under the OSI-approved BSD License (the "License");
|
||
|
|
# see accompanying file Copyright.txt for details.
|
||
|
|
#
|
||
|
|
# This software is distributed WITHOUT ANY WARRANTY; without even the
|
||
|
|
# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
|
||
|
|
# See the License for more information.
|
||
|
|
#=============================================================================
|
||
|
|
# (To distribute this file outside of CMake, substitute the full
|
||
|
|
# License text for the above reference.)
|
||
|
|
|
||
|
|
#
|
||
|
|
# Extra arguments added by libarchive
|
||
|
|
# CMAKE_REQUIRED_LINKER_FLAGS = string of linker command line flags
|
||
|
|
#
|
||
|
|
|
||
|
|
include(CMakeExpandImportedTargets)
|
||
|
|
|
||
|
|
|
||
|
|
macro(LIBARCHIVE_CHECK_C_SOURCE_COMPILES SOURCE VAR)
|
||
|
|
if("${VAR}" MATCHES "^${VAR}$")
|
||
|
|
set(_FAIL_REGEX)
|
||
|
|
set(_key)
|
||
|
|
foreach(arg ${ARGN})
|
||
|
|
if("${arg}" MATCHES "^(FAIL_REGEX)$")
|
||
|
|
set(_key "${arg}")
|
||
|
|
elseif(_key)
|
||
|
|
list(APPEND _${_key} "${arg}")
|
||
|
|
else()
|
||
|
|
message(FATAL_ERROR "Unknown argument:\n ${arg}\n")
|
||
|
|
endif()
|
||
|
|
endforeach()
|
||
|
|
set(MACRO_CHECK_FUNCTION_DEFINITIONS
|
||
|
|
"-D${VAR} ${CMAKE_REQUIRED_FLAGS}")
|
||
|
|
if(CMAKE_REQUIRED_LIBRARIES)
|
||
|
|
# this one translates potentially used imported library targets to their files on disk
|
||
|
|
CMAKE_EXPAND_IMPORTED_TARGETS(_ADJUSTED_CMAKE_REQUIRED_LIBRARIES LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} CONFIGURATION "${CMAKE_TRY_COMPILE_CONFIGURATION}")
|
||
|
|
set(CHECK_C_SOURCE_COMPILES_ADD_LIBRARIES
|
||
|
|
"-DLINK_LIBRARIES:STRING=${_ADJUSTED_CMAKE_REQUIRED_LIBRARIES}")
|
||
|
|
else()
|
||
|
|
set(CHECK_C_SOURCE_COMPILES_ADD_LIBRARIES)
|
||
|
|
endif()
|
||
|
|
if(CMAKE_REQUIRED_INCLUDES)
|
||
|
|
set(CHECK_C_SOURCE_COMPILES_ADD_INCLUDES
|
||
|
|
"-DINCLUDE_DIRECTORIES:STRING=${CMAKE_REQUIRED_INCLUDES}")
|
||
|
|
else()
|
||
|
|
set(CHECK_C_SOURCE_COMPILES_ADD_INCLUDES)
|
||
|
|
endif()
|
||
|
|
if(CMAKE_REQUIRED_LINKER_FLAGS)
|
||
|
|
set(CHECK_C_SOURCE_COMPILES_ADD_LINKER_FLAGS
|
||
|
|
"-DCMAKE_EXE_LINKER_FLAGS:STRING=${CMAKE_REQUIRED_LINKER_FLAGS} -DCMAKE_SHARED_LINKER_FLAGS:STRING=${CMAKE_REQUIRED_LINKER_FLAGS} -DCMAKE_MODULE_LINKER_FLAGS:STRING=${CMAKE_REQUIRED_LINKER_FLAGS}")
|
||
|
|
else()
|
||
|
|
set(CHECK_C_SOURCE_COMPILES_ADD_LINKER_FLAGS)
|
||
|
|
endif()
|
||
|
|
file(WRITE "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/src.c"
|
||
|
|
"${SOURCE}\n")
|
||
|
|
|
||
|
|
message(STATUS "Performing Test ${VAR}")
|
||
|
|
try_compile(${VAR}
|
||
|
|
${CMAKE_BINARY_DIR}
|
||
|
|
${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/src.c
|
||
|
|
COMPILE_DEFINITIONS ${CMAKE_REQUIRED_DEFINITIONS}
|
||
|
|
CMAKE_FLAGS -DCOMPILE_DEFINITIONS:STRING=${MACRO_CHECK_FUNCTION_DEFINITIONS} ${CHECK_C_SOURCE_COMPILES_ADD_LINKER_FLAGS}
|
||
|
|
"${CHECK_C_SOURCE_COMPILES_ADD_LIBRARIES}"
|
||
|
|
"${CHECK_C_SOURCE_COMPILES_ADD_INCLUDES}"
|
||
|
|
OUTPUT_VARIABLE OUTPUT)
|
||
|
|
|
||
|
|
foreach(_regex ${_FAIL_REGEX})
|
||
|
|
if("${OUTPUT}" MATCHES "${_regex}")
|
||
|
|
set(${VAR} 0)
|
||
|
|
endif()
|
||
|
|
endforeach()
|
||
|
|
|
||
|
|
if(${VAR})
|
||
|
|
set(${VAR} 1 CACHE INTERNAL "Test ${VAR}")
|
||
|
|
message(STATUS "Performing Test ${VAR} - Success")
|
||
|
|
file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeOutput.log
|
||
|
|
"Performing C SOURCE FILE Test ${VAR} succeded with the following output:\n"
|
||
|
|
"${OUTPUT}\n"
|
||
|
|
"Source file was:\n${SOURCE}\n")
|
||
|
|
else()
|
||
|
|
message(STATUS "Performing Test ${VAR} - Failed")
|
||
|
|
set(${VAR} "" CACHE INTERNAL "Test ${VAR}")
|
||
|
|
file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log
|
||
|
|
"Performing C SOURCE FILE Test ${VAR} failed with the following output:\n"
|
||
|
|
"${OUTPUT}\n"
|
||
|
|
"Source file was:\n${SOURCE}\n")
|
||
|
|
endif()
|
||
|
|
endif()
|
||
|
|
endmacro()
|
||
|
|
|